@echo off
:_max
mode con: cols=62 lines=23
set bt=MaxDOS V6 系統(tǒng)備份查看器. 邁思工作室 Http://Pzz.Cn
color f0
title %bt%

:_m1
cls
echo.
echo MaxDOS V6 系統(tǒng)備份查看器
echo ═════════════════════════════
echo.
echo 1、打開存放備份鏡像的目錄
echo 2、刪除已存在的鏡像備份文件
echo 3、刪除用于存放鏡像的備份目錄
echo 4、將用于存放鏡像的目錄設(shè)為可見
echo 5、將用于存放鏡像的目錄設(shè)為隱藏
echo 6、關(guān)閉備份文件夾(MaxBAK)的防刪除保護
echo 7、打開備份文件夾(MaxBAK)的防刪除保護
echo.
echo ═════════════════════════════
set pd=0
for %%m in (j i h g f e d) do if exist %%m:\maxbak set pd=%%m
set bf=MaxBAK\sysbak.max
set scd=0
for %%i in (j i h g f e d) do if exist %%i:\%bf% set scd=%%i
if %scd%==0 goto _ghoerr
echo 在 %scd%:\%bf% 發(fā)現(xiàn)使用MaxDOS一鍵備份生成的鏡像.
goto _me
:_ghoerr
echo 對不起,未發(fā)現(xiàn)使用MaxDOS一鍵備份生成的鏡像,請及時備份系統(tǒng).
:_me
echo.
echo 為了避免GHOST備份的鏡像被病毒刪除故將MaxDOS一鍵備份生成的
echo 鏡像保存為 sysbak.max 命名,存放于分區(qū)根目錄的MaxBAK目錄下.
echo.
set chi=
set /p chi= 請選擇操作后回車:

if '%chi%'=='' goto _m1
if /i '%chi%'=='1' goto _op
if /i '%chi%'=='2' goto _dbakf
if /i '%chi%'=='3' goto _rdbak
if /i '%chi%'=='4' goto _atton
if /i '%chi%'=='5' goto _attof
if /i '%chi%'=='6' goto _cld
if /i '%chi%'=='7' goto _omd
goto _m1

:_cld
if %pd%==0 goto _er1
@rd /s /q %pd%:\MaxBAK\NODEL..\ >nul
@echo 已經(jīng)關(guān)閉備份文件夾(MaxBAK)的防刪除保護,按任意鍵返回!
pause >nul
goto _m1

:_omd
if %pd%==0 goto _er1
@md %pd%:\MaxBAK\NODEL..\ >nul
@echo 已經(jīng)打開備份文件夾(MaxBAK)的防刪除保護,按任意鍵返回!
pause >nul
goto _m1

:_op
if %pd%==0 goto _er1
start %pd%:\MaxBAK
goto _m1

:_dbakf
if %scd%==0 goto _er1
set /p yndel= 是否需要真的刪除備份文件? [y=是 n=否]:
if '%yndel%'=='' goto _m1
if '%yndel%'=='y' del /f %scd%:\%bf%
if '%yndel%'=='n' goto _m1
echo 刪除完成,按任意鍵返回.
pause >nul
goto _m1

:_atton
if %pd%==0 goto _er1
for %%k in (d: e: f: g:) do if exist %%k\MaxBAK\nul attrib -s -r -h %%k\MaxBAK
echo 已經(jīng)將備份目錄設(shè)為可見,按任意鍵返回.
pause >nul
goto _m1

:_attof
if %pd%==0 goto _er1
for %%j in (d: e: f: g:) do if exist %%j\MaxBAK\nul attrib +s +r +h %%j\MaxBAK
echo 已經(jīng)將所有備份目錄設(shè)為隱藏,按任意鍵返回.
pause >nul
goto _m1

:_rdbak
if %pd%==0 goto _er1
for %%l in (d: e: f: g:) do if exist %%l\MaxBAK\nul rd %%l\MaxBAK /s /q >nul
echo 刪除完成,按任意鍵返回.
pause >nul
goto _m1

:_er1
echo 對不起未發(fā)現(xiàn)備份文件或備份文件夾,此功能失效,按任意鍵返回!
pause >nul
goto _m1

:exit