@echo off
:: 普通的 for+findstr 語(yǔ)句會(huì)忽略分號(hào)開(kāi)頭的行
:: findstr /n .* 用delims=:后，會(huì)忽略行首所有的冒號(hào)
:: 還有!、、.等特殊符號(hào)需要處理
:: 以下代碼可以準(zhǔn)確提取這些敏感字符
:: 解決了 setlocal 最大遞歸層的問(wèn)題(setlocal 兩兩嵌套處理超過(guò)15行內(nèi)容時(shí)會(huì)帶來(lái)此問(wèn)題)
:: 能計(jì)算空行
:: code by jm 2006-12-12 thanks 3742668 CMD@XP
set num=0
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
setlocal enabledelayedexpansion
echo 第 !num! 行： !str:*:=!
endlocal
)
pause
goto :eof
@echo off
:: 超過(guò)15行內(nèi)容時(shí)，會(huì)帶來(lái) setlocal 最大遞歸層的問(wèn)題
:: code by 3742668 2006-12-11 CMD@XP
@echo off
setlocal enabledelayedexpansion
set num=
for /f "eol= delims=" %%i in ('findstr .* a.txt') do (
setlocal DISABLEDELAYEDEXPANSION
set "tmpstr=%%i"
setlocal enabledelayedexpansion
set /a num += 1
set "!num!=!tmpstr!"
)
for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
exit /b 0
@echo off
:: 不能正確提取帶感嘆號(hào)的內(nèi)容
:: code by jm 2006-12-11 CMD@XP
set num=0
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
echo 第 !num! 行： !str:*:=!
)
pause
goto :eof
@echo off
:: 結(jié)果要用引號(hào)括起來(lái)
:: code by jm 2006-12-11 CMD@XP
set num=0
::setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
call :display
)
pause
goto :eof
:display
echo 第 %num% 行： "%str:*:=%"
goto :eof
test.txt的內(nèi)容
:abc
::xy

;;;ef
;:;
::;;


^
!
!
%
"
""
'
test
abc