雖然大家學(xué)過了一些Windows的命令,但用批處理來與用戶交互并實現(xiàn)自動關(guān)機可能還沒有試過吧.自己做一個關(guān)機程序,感覺可不一樣.下面我們就利用Windows 的批處理腳本,來實現(xiàn)自動關(guān)機的功能,程序不算復(fù)雜,功能可一點都不少哦!本程序在Windows xp/2000/2003環(huán)境下測試通過.
第一步:
打開記事本,輸入下面的文字(以rem開頭的語句是注釋,可以不必輸入).
復(fù)制代碼 代碼如下:
@echo off
title 自動關(guān)機程序 作者:青劍
rem 這里改成你的名字好了
color 17
rem 如果你不喜歡命令行默認(rèn)的黑底白字模式,可以用color命令進(jìn)行更改,上面"17"代表藍(lán)底白字.
:start
echo.
echo.
echo 請選擇要進(jìn)行的操作，然后按回車：
echo.
echo 1. 定時關(guān)機
echo 2. 倒計時關(guān)機
echo 3. 刪除定時關(guān)機任務(wù)
echo 4. 查看定時關(guān)機任務(wù)狀態(tài)
echo 5. 注銷
echo 6. 退出
echo.
:set
SET a=
SET /P a=選擇:
rem 設(shè)定變量"a"為用戶輸入的字符
IF NOT '%a%'=='' SET a=%a:~0,1%
ECHO.
IF /I '%a%'=='1' goto 1
IF /I '%a%'=='2' goto 2
IF /I '%a%'=='3' goto 3
IF /I '%a%'=='4' goto 4
IF /I '%a%'=='5' goto 5
IF /I '%a%'=='6' goto 6
rem 如果輸入的字符不是1-6,將返回重新輸入
echo %a% 選擇無效，請重新輸入：
echo.
goto set
:1
echo 請輸入關(guān)機時間,(如12:00:00)
set shutdowntime=
set /p shutdowntime=
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
rem 如果輸入正確,就執(zhí)行:ok后面的語句
echo %shutdowntime% 不是標(biāo)準(zhǔn)的時間格式,請重新輸入
echo.
goto 1
:ok
echo.
echo 設(shè)定完畢! 按任意鍵繼續(xù)...
pause >nul
cls
goto start
:2
echo 您想要多少秒后關(guān)機
echo (若設(shè)定后要取消,單擊"確定"后按Ctrl+C鍵兩次)
set timed=
set /p timed=輸入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 goto ok
echo %timed% 是無效的關(guān)機時間,請重新輸入
echo.
goto 2
:3
at /del /y
echo 定時關(guān)機任務(wù)已取消,按任意鍵繼續(xù)...
pause >nul
cls
goto start
:4
at
echo 按任意鍵繼續(xù)...
pause >nul
cls
goto start
:5
logoff
:6
exit
第二步:
輸入完畢后,保存文件,在"保存"對話框中將"保存類型"選擇為"所有文件",文件名為"自動關(guān)機程序.bat"即可.
第三步:
看看這個程序的后綴名是bat的,而且圖標(biāo)也很土,不要急,我們可以用WinRAR3.0以上版本將這個批處理文件做成一個exe文件,方法如下:
如果你的系統(tǒng)未安裝WinRAR請先安裝
選擇"自動關(guān)機程序.bat",在右鍵菜單中選擇"添加到檔案文件(A)…"
在"壓縮選項"中選擇"創(chuàng)建自釋放格式檔案文件"
單擊"高級"標(biāo)簽,單擊"SFX選項",打開"高級自釋放選項"在"常規(guī)"選項卡中"釋放后運行"內(nèi)輸入壓縮的文件名"自動關(guān)機程序.bat"
單擊"模式"標(biāo)簽,選擇"解包到臨時文件夾",在緘默模式"內(nèi)選擇"全部隱藏",在"覆蓋方式"內(nèi)選擇"覆蓋所有文件"
如果您要更改默認(rèn)的圖標(biāo),可以打開"文本和圖標(biāo)"標(biāo)簽,在"自定義SFX文件圖標(biāo)"的"從文件載入SFX圖標(biāo)"下的文本框中輸入或瀏覽您喜歡的圖標(biāo)所在路徑.如果你沒有準(zhǔn)備圖標(biāo),可以打開系統(tǒng)所在盤后,使用搜索,在搜索文件名內(nèi)輸入"*.ico"就可以找到很多圖標(biāo)了，把找到的圖標(biāo)路徑和文件名輸入文本框即可.
依次確定后,即在原文件夾內(nèi)多了一個"自動關(guān)機程序.exe"的文件了,大功現(xiàn)已造成啦!
您可能感興趣的文章:- VBS 斷網(wǎng)后自動關(guān)機30秒后
- emule自動關(guān)機腳本
- vbs實現(xiàn)的eMule電驢自動關(guān)機腳本代碼
- 可以實現(xiàn)系統(tǒng)自動關(guān)機的批處理
- 用bat實現(xiàn)的自動關(guān)機的代碼
- 可以定時自動關(guān)機的vbs腳本
- bat定時自動關(guān)機,bat自動結(jié)束任務(wù)關(guān)閉程序,dos自動結(jié)束程序后關(guān)機
