新增的APPLY表運(yùn)算符把右表表達(dá)式應(yīng)用到左表表達(dá)式中的每一行。它不像JOIN那樣先計(jì)算那個(gè)表表達(dá)式都可以，APPLY必選先邏輯地計(jì)算左表達(dá)式。這種計(jì)算輸入的邏輯順序允許吧右表達(dá)式關(guān)聯(lián)到左表表達(dá)式。
APPLY有兩種形式，一個(gè)是OUTER APPLY，一個(gè)是CROSS APPLY，區(qū)別在于指定OUTER，意味著結(jié)果集中將包含使右表表達(dá)式為空的左表表達(dá)式中的行，而指定CROSS，則相反，結(jié)果集中不包含使右表表達(dá)式為空的左表表達(dá)式中的行。
用幾個(gè)例子解釋這個(gè)會(huì)更清晰。
例1：CROSS APPLY 形式
比如：LargeTable表中的某一列存儲(chǔ)的數(shù)據(jù)是以“:”號(hào)分隔的數(shù)據(jù)，我們處理的時(shí)候，可能要先把這個(gè)值，先分隔，然后把分隔后的每個(gè)值單獨(dú)一行放在一張表中，然后對(duì)這個(gè)表做處理。
原始數(shù)據(jù)（LargeTable表）：
為了簡(jiǎn)單，我們先拿其中id=2的一行處理，這些以:號(hào)分隔的數(shù)據(jù)，可能是我們某張表的主鍵（t1），我們可能需要把這些數(shù)值提出來(lái)，放在一張臨時(shí)表中，和t1表關(guān)聯(lián)，做一些處理。
處理這個(gè)分隔的數(shù)據(jù)結(jié)果如下圖：
如果用之前的版本處理這個(gè)操作的話，應(yīng)該很發(fā)雜，暫時(shí)沒(méi)想到怎么處理，如果有人實(shí)現(xiàn)過(guò)，可以提示一下。
這只是用其中一行做的處理，如果我們用上圖的3行都做這樣處理，把三行以:號(hào)分隔的數(shù)值都放在一個(gè)表中，該怎么處理呢？
今天的主角APPLY該閃亮登場(chǎng)了。用APPLY表運(yùn)算符一行語(yǔ)句就能處理以上操作。
復(fù)制代碼 代碼如下:
SELECT a FROM dbo.LargeTable AS LT --實(shí)際表
CROSS APPLY dbo.split(LT.Name,':') --自定義表值函數(shù)，處理以某個(gè)字符分隔的數(shù)據(jù)，把這些數(shù)據(jù)，返回一張表
WHERE a > '' --去掉結(jié)果表中a字段為空的數(shù)據(jù)
處理的結(jié)果如下圖：
是不是很簡(jiǎn)單。
需要額外定義的就是那個(gè)自定義表值函數(shù)（split），這是我在網(wǎng)上找的，類似.Net中Split操作，代碼如下：
復(fù)制代碼 代碼如下:
/*
使用方法：SELECT * FROM dbo.split('581::579::519::279::406::361::560',':')
*/
ALTER Function [dbo].[Split](@Sql varchar(8000),@Splits varchar(10))
returns @temp Table (a varchar(100))
As
Begin
Declare @i Int
Set @Sql = RTrim(LTrim(@Sql))
Set @i = CharIndex(@Splits,@Sql)
While @i >= 1
Begin
Insert @temp Values(Left(@Sql,@i-1))
Set @Sql = SubString(@Sql,@i+1,Len(@Sql)-@i)
Set @i = CharIndex(@Splits,@Sql)
End
If @Sql > ''
Insert @temp Values (@Sql)
Return
End
例2：OUTER APPLY 形式
場(chǎng)景：有個(gè)供貨商表（Supplier）和供貨商產(chǎn)品表（Products）,我們要取每一個(gè)供貨商中單價(jià)最高的兩個(gè)產(chǎn)品。
供貨商表：
供貨商產(chǎn)品表：
首先，我們創(chuàng)建一個(gè)自定義表值函數(shù)（dbo.fn_top_products），該函數(shù)根據(jù)供貨商ID返回單價(jià)最高的兩個(gè)商品。
復(fù)制代碼 代碼如下:
IF OBJECT_ID('dbo.fn_top_products') IS NOT NULL
DROP FUNCTION dbo.fn_top_products;
GO
--根據(jù)供貨商ID獲得單價(jià)最高的兩件商品
CREATE FUNCTION dbo.fn_top_products
(@supid AS INT)
RETURNS TABLE
AS
RETURN
SELECT TOP(2)Id AS ProductId,ProductName,UnitPrice
FROM dbo.Products
WHERE SupplierId = @supid
ORDER BY UnitPrice DESC
GO
好，前期的數(shù)據(jù)都已經(jīng)準(zhǔn)備好了，下面讓我們?cè)囋囉肙UTER APPLY形式來(lái)查詢，會(huì)出現(xiàn)什么結(jié)果。
執(zhí)行以下語(yǔ)句：
復(fù)制代碼 代碼如下:
SELECT S.id AS SupplierId,S.CompanyName,UnitPrice FROM dbo.Supplier AS S
OUTER APPLY dbo.fn_top_products(S.id) AS P
執(zhí)行結(jié)果如下：
注意最后為NULL的記錄，reed公司因?yàn)闆](méi)有商品，所以單價(jià)為NULL了。
如果用CROSS APPLY形式，執(zhí)行以下查詢：
復(fù)制代碼 代碼如下:
SELECT S.id AS SupplierId,S.CompanyName,UnitPrice FROM dbo.Supplier AS S
CROSS APPLY dbo.fn_top_products(S.id) AS P
生成的輸出結(jié)果如下：
大家看出OUTER APPLY和CROSS APPLY的區(qū)別了吧。
再次說(shuō)一下APPLY的執(zhí)行過(guò)程，它先邏輯計(jì)算左表表達(dá)式（以上的LargeTable表），然后把右表達(dá)式（以上的自定義表值函數(shù)Split）應(yīng)用到左表表達(dá)式的每一行。實(shí)際是把外部查詢的列引用作為參數(shù)傳遞給表值函數(shù)。
